cmake_minimum_required(VERSION 3.5)

project(ActorViewer VERSION 0.1 LANGUAGES CXX)

set(CMAKE_INCLUDE_CURRENT_DIR ON)

set(CMAKE_AUTOUIC ON)
set(CMAKE_AUTOMOC ON)
set(CMAKE_AUTORCC ON)

set(CMAKE_CXX_STANDARD 17)
set(CMAKE_CXX_STANDARD_REQUIRED ON)
set(CMAKE_EXPORT_COMPILE_COMMANDS ON) # For Kate's LSP

find_package(QT NAMES Qt5 REQUIRED COMPONENTS Widgets Concurrent)
find_package(Qt${QT_VERSION_MAJOR} REQUIRED COMPONENTS Widgets Concurrent)

# Compile option for mastodonpp support
option(MASTODONPP_BUILD "Build a version with mastodonpp support" ON)

# Get Git commit hash, from http://xit0.org/2013/04/cmake-use-git-branch-and-commit-details-in-project/
# Get a human-readable name of the latest commit on the current branch
execute_process(
  COMMAND git log -1 "--format=%(describe)"
  WORKING_DIRECTORY ${CMAKE_SOURCE_DIR}
  OUTPUT_VARIABLE GIT_DESCRIBE_TEXT
  OUTPUT_STRIP_TRAILING_WHITESPACE
)
if (GIT_DESCRIBE_TEXT)
    # Put the hash between " so it is a string litteral
    string(PREPEND GIT_DESCRIBE_TEXT "\"")
    string(APPEND GIT_DESCRIBE_TEXT "\"")
else()
    # Get the latest commit hash of the working branch
    execute_process(
      COMMAND git log -1 --format=%H
      WORKING_DIRECTORY ${CMAKE_SOURCE_DIR}
      OUTPUT_VARIABLE GIT_COMMIT_HASH
      OUTPUT_STRIP_TRAILING_WHITESPACE
    )
    string(PREPEND GIT_COMMIT_HASH "\"")
    string(APPEND GIT_COMMIT_HASH "\"")
endif()

# add_subdirectory will happen later…
set(PROJECT_SOURCES
        src/main.cpp
        src/mainwindow.cpp
        src/mainwindow.h
        src/mainwindow.ui
        src/finddialog.cpp
        src/finddialog.h
        src/finddialog.ui
        src/settingsdialog.cpp
        src/settingsdialog.h
        src/settingsdialog.ui
        src/aboutdialog.cpp
        src/aboutdialog.h
        src/aboutdialog.ui
        src/settings_interface.cpp
        src/settings_interface.h
        src/widgets/status_info.cpp
        src/widgets/status_info.h
        src/widgets/status_info.ui
        src/widgets/tab_activity_list.cpp
        src/widgets/tab_activity_list.h
        src/widgets/tab_activity_list.ui
        src/widgets/tab_actor_info.cpp
        src/widgets/tab_actor_info.h
        src/widgets/tab_actor_info.ui
        src/archive/base_archive.cpp
        src/archive/base_archive.h
        src/archive/mastodon.cpp
        src/archive/mastodon.h
        src/types.h
        src/list_item.cpp
        src/list_item.h
        src/command_line.cpp
        src/command_line.h
        src/net/instance.cpp
        src/net/instance.h
        src/activitypub/fields.h
        src/activitypub/apactivity.h
        src/activitypub/apactor.h
        src/activitypub/apattachment.h
        src/activitypub/apbase.h
        src/activitypub/apobject.h
        src/activitypub/appost.h
        src/activitypub/apreblog.h
        src/activitypub/apquestion.h
        src/activitypub/apactivity.cpp
        src/activitypub/apactor.cpp
        src/activitypub/apattachment.cpp
        src/activitypub/apbase.cpp
        src/activitypub/apobject.cpp
        src/activitypub/appost.cpp
        src/activitypub/apreblog.cpp
        src/activitypub/apquestion.cpp
)

if(MASTODONPP_BUILD)
    list(APPEND PROJECT_SOURCES
        src/net/mastodon_instance.cpp
        src/net/mastodon_instance.h
    )
endif()

if(${QT_VERSION_MAJOR} GREATER_EQUAL 6)
    qt_add_executable(ActorViewer
        MANUAL_FINALIZATION
        ${PROJECT_SOURCES}
    )
# Define target properties for Android with Qt 6 as:
#    set_property(TARGET ActorViewer APPEND PROPERTY QT_ANDROID_PACKAGE_SOURCE_DIR
#                 ${CMAKE_CURRENT_SOURCE_DIR}/android)
# For more information, see https://doc.qt.io/qt-6/qt-add-executable.html#target-creation
else()
    if(ANDROID)
        add_library(ActorViewer SHARED
            ${PROJECT_SOURCES}
        )
# Define properties for Android with Qt 5 after find_package() calls as:
#    set(ANDROID_PACKAGE_SOURCE_DIR "${CMAKE_CURRENT_SOURCE_DIR}/android")
    else()
        add_executable(ActorViewer
            ${PROJECT_SOURCES}
        )
    endif()
endif()

if(MASTODONPP_BUILD)
    # Set build options for mastodonpp
    # See https://stackoverflow.com/a/20239564
    set(BUILD_SHARED_LIBS OFF CACHE INTERNAL "")

    add_subdirectory(${CMAKE_CURRENT_SOURCE_DIR}/lib/mastodonpp EXCLUDE_FROM_ALL)
    # -fsanitize=undefined is required for linking, as else you get undefined symbols
    target_link_libraries(ActorViewer PRIVATE mastodonpp -fsanitize=undefined)

    # Define preprocessor macro MASTODONPP_BUILD
    target_compile_definitions(ActorViewer PRIVATE MASTODONPP_BUILD)
endif()

configure_file(gen/git_version.h.in gen/git_version.h)
target_include_directories(ActorViewer PRIVATE gen)

target_link_libraries(ActorViewer PRIVATE Qt${QT_VERSION_MAJOR}::Widgets)

set_target_properties(ActorViewer PROPERTIES
    MACOSX_BUNDLE_GUI_IDENTIFIER space.twilightsparkle.ActorViewer
    MACOSX_BUNDLE_BUNDLE_VERSION ${PROJECT_VERSION}
    MACOSX_BUNDLE_SHORT_VERSION_STRING ${PROJECT_VERSION_MAJOR}.${PROJECT_VERSION_MINOR}
    MACOSX_BUNDLE TRUE
    WIN32_EXECUTABLE TRUE
)

install(TARGETS ActorViewer
    BUNDLE DESTINATION .
    LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR})

if(QT_VERSION_MAJOR EQUAL 6)
    qt_finalize_executable(ActorViewer)
endif()